home *** CD-ROM | disk | FTP | other *** search
/ Ham Radio 2000 #1 / Ham Radio 2000.iso / ham2000 / vhf / mspred / meteor.bas < prev   
Encoding:
BASIC Source File  |  1990-08-17  |  20.5 KB  |  454 lines
  1.  
  2. 10 CLS : KEY OFF
  3. 20 PRINT : PRINT "           ***************** METEOR *******************": PRINT
  4. 30 PRINT "                 METEOR SCATTER PREDICTION PROGRAM"
  5. 40 PRINT "                      MICHAEL R. OWEN, W9IP"
  6. 50 PRINT "                          21 MAPLE ST."
  7. 60 PRINT "                       CANTON, NY  13617"
  8. 70 PRINT
  9. 80  REM ***  THIS PROGRAM CALCULATES THE PEAK TIME FOR MAJOR METEOR
  10. 90  REM ***  SHOWERS.  IT ALSO PROVIDES INFORMATION CONCERNING THE
  11. 100 REM ***  OPTIMUM TIMES FOR PARTICULAR PATHS, IN GRAPHIC AND TABLE
  12. 110 REM ***  FORM.  THE PROGRAM IS WRITTEN FOR THE IBM-PC AND ALL
  13. 120 REM ***  COMPATIBLE COMPUTERS (MS-DOS OR PC-DOS, PLUS BASICA).
  14. 130 REM   ***********************************************************
  15. 140 REM   * PLEASE NOTE: YOU MUST ENTER YOUR OWN LATUTUDE AND       *
  16. 150 REM   * LONGITUDE ON LINES 190 AND 200 BELOW.  REMEMBER THAT    *
  17. 160 REM   * SOUTH LATITUDES AND WEST LONGITUDES ARE NEGATIVE.       *
  18. 170 REM   * YOU WILL ALSO WANT TO CHECK THE DEFAULT YEAR (LINE 3720)*
  19. 180 REM   ***********************************************************
  20. 190 MYLATD = 60.1: REM *** SOUTH LATITUDES ARE NEGATIVE!
  21. 200 MYLOND = 24.8: REM *** WEST LONGITUDES ARE NEGATIVE!
  22. 210 REM *** PC BASIC DOESN'T HAVE ARCCOS OR ARCSIN, SO DEFINE FUNCTIONS HERE
  23. 220 DEF FNACOS (X) = 1.570796 - ATN(X / SQR(1.000001 - X * X))
  24. 230 DEF FNARSIN (X) = ATN(X / SQR(1! - X * X))
  25. 240 DIM LDATE(400), LTIME(400), LELEV(400), LAZIM(400)
  26. 250 REM *************************************
  27. 260 REM INITIALIZING PROGRAM: SETTING OPTIONS
  28. 270 REM *************************************
  29. 280 LENG = 0: INCR = 0: COUNTR = 0: ENDER = 1: BEST = 0: HEADER = 0: OPTDIR = 0: BESEL = 90
  30. 290 GOSUB 4400
  31. 300 IF COUNTR = 1 THEN CLS
  32. 310 PRINT : PRINT : PRINT
  33. 320 PRINT "                         OPTIONS:"
  34. 330 PRINT
  35. 340 PRINT "       1)  PEAK TIME PREDICTION"
  36. 350 PRINT "       2)  (1) PLUS GRAPH OF AZ/EL OF RADIANT FOR A PARTICULAR PATH"
  37. 360 PRINT "       3)  LISTING OF GOOD TIMES FOR ALL PATHS"
  38. 370 PRINT "       4)  BEST PATH FOR A PARTICULAR TIME"
  39. 380 PRINT
  40. 390 PRINT
  41. 400 INPUT "WHAT IS YOUR CHOICE (1-4)"; WHICH
  42. 410 IF WHICH < 1 OR WHICH > 4 THEN 400
  43. 420 IF WHICH <> 2 THEN 550
  44. 430 CLS : PRINT "WHICH GENERAL DIRECTION?"
  45. 440 PRINT : PRINT
  46. 450 PRINT "1) NORTH": PRINT "2) NORTHEAST": PRINT "3) EAST"
  47. 460 PRINT "4) SOUTHEAST": PRINT "5) SOUTH": PRINT "6) SOUTHWEST"
  48. 470 PRINT "7) WEST": PRINT "8) NORTHWEST"
  49. 480 PRINT : PRINT "9) SPECIFIC LAT,LON          (SOUTH LAT AND WEST LON ARE NEGATIVE)"
  50. 490 PRINT : PRINT "10) SPECIFIC BEARING FROM YOUR QTH (0-360)"
  51. 500 PRINT : PRINT : PRINT : INPUT "CHOOSE DIRECTION BY NUMBER (1-10)"; DIRECTION
  52. 510 IF DIRECTION < 1 OR DIRECTION > 10 THEN 500
  53. 520 IF WHICH <> 2 THEN 550
  54. 530 IF DIRECTION = 9 THEN INPUT "OTHER STATION'S LAT,LONG "; HISLATD, HISLOND: GOSUB 3270
  55. 540 IF DIRECTION = 10 THEN INPUT "BEARING (DEGREES)"; LOOK
  56. 550 CLS : PRINT : PRINT : PRINT "      METEOR SHOWER"; TAB(27); "DATE"
  57. 560 PRINT
  58. 570 PRINT "    1)  QUADRANTIDS "; TAB(25); " 4 JANUARY"
  59. 580 PRINT "    2)  LYRIDS      "; TAB(25); "22 APRIL"
  60. 590 PRINT "    3)  ETA AQUARIDS"; TAB(25); " 4 MAY"
  61. 600 PRINT "    4)  ARIETIDS    "; TAB(25); " 7 JUNE"
  62. 610 PRINT "    5)  PERSEIDS    "; TAB(25); "12 AUGUST"
  63. 620 PRINT "    6)  DRACONIDS   "; TAB(25); "10 OCTOBER"
  64. 630 PRINT "    7)  ORIONIDS    "; TAB(25); "20 OCTOBER"
  65. 640 PRINT "    8)  LEONIDS     "; TAB(25); "17 NOVEMBER"
  66. 650 PRINT "    9)  GEMINIDS    "; TAB(25); "13 DECEMBER"
  67. 660 PRINT : PRINT : PRINT
  68. 670 INPUT "FOR WHICH SHOWER DO YOU WANT INFORMATION (1-9)"; SHOWER
  69. 680 IF SHOWER < 1 OR SHOWER > 9 THEN 670
  70. 690 GOSUB 3670: IF WHICH = 1 THEN 2400
  71. 700 IF WHICH = 4 THEN PRINT : PRINT : INPUT "WHAT TIME (OPT. 4)"; STARTTIME: GOTO 780
  72. 710 PRINT : PRINT "FOR THIS RUN,                       DEFAULT VALUES IN [ ]"
  73. 720 PRINT : INPUT "HOW LONG? (HOURS)  [24]  "; LENG
  74. 730 IF LENG = 0 THEN LENG = 24: REM *** DEFAULT ON EMPTY RETURN
  75. 740 LENG = LENG * 100
  76. 750 INPUT "WHAT INCREMENT (MINUTES)  [60]  "; INCR
  77. 760 IF INCR = 0 THEN INCR = 60: REM *** DEFAULT ON EMPTY RETURN
  78. 770 IF INCR > 60 THEN INCR = CINT((INCR / 60) * 100)
  79. 780 PRINT "DO YOU WANT INFORMATION FOR THE PEAK DAY ("; M; "/"; DAY; ")?   [Y]  ": INPUT CENT$
  80. 790 IF CENT$ <> "N" THEN CENT$ = "Y": REM *** DEFAULT ON EMPTY RETURN
  81. 800 IF CENT$ = "Y" THEN 820
  82. 810 INPUT "WHAT DATE DO YOU WANT (MONTH, DAY)"; M, DAY
  83. 820 IF WHICH = 4 THEN 870
  84. 830 INPUT "START TIME, UTC (EXAMPLE: 0000)   [0000]  "; STARTTIME
  85. 840 REM *** STARTTIME=0 IS AUTOMATIC
  86. 850 REM *** THIS LOOP "LOOKS" AROUND THE COMPASS AT 45 DEGREE INCREMENTS
  87. 860 IF WHICH = 3 THEN FOR DIRECTION = 1 TO 8
  88. 870 ROUNDS = 0
  89. 880 TIME = STARTTIME
  90. 890 TIMECOUNT = TIME
  91. 900 FINISH = TIMECOUNT + LENG + 100
  92. 910 GOSUB 2490: T = S * 15 * R1
  93. 920 IF COUNTR > 0 THEN 1070
  94. 930 REM *** INPUT RIGHT ASCENSION DATA: RAHOUR, RAMIN IN DATA STATEMENT.
  95. 940 REM *** A$ IS HOURS, A2 IS MIN, A3 IS SEC.
  96. 950 REM *** CHANGE THESE OR WRITE AN INPUT STATEMENT IF YOU WANT TO
  97. 960 REM *** EVALUATE OTHER METEOR SHOWERS (OR OTHER CELESTIAL OBJECTS)
  98. 970 A$ = STR$(RAHOUR): A2 = RAMIN: A3 = 0
  99. 980 GOSUB 2420: R = A * 15 * R1
  100. 990 REM *** INPUT DECLINATION, SAME COMMENTS AS ABOVE
  101. 1000 A$ = STR$(DEC): A2 = 0: A3 = 0
  102. 1010 GOSUB 2420: DEG = A * R1
  103. 1020 IF WHICH <> 4 THEN 1070
  104. 1030 PRINT : PRINT : PRINT "PLEASE WAIT"
  105. 1040 FOR BESTDIR = 0 TO 355 STEP 5
  106. 1050 ANGLE = BESTDIR
  107. 1060 GOTO 1210
  108. 1070 IF WHICH = 2 AND COUNTR = 1 THEN 1240
  109. 1080 REM *** THIS SECTION CHOOSES PATHS IN 45 DEGREE STEPS
  110. 1090 IF DIRECTION = 9 THEN GOSUB 3270: GOSUB 2810: GOTO 1270
  111. 1100 IF DIRECTION = 1 THEN ANGLE = 0: WAY$ = "N"
  112. 1110 IF DIRECTION = 2 THEN ANGLE = 45: WAY$ = "NE"
  113. 1120 IF DIRECTION = 3 THEN ANGLE = 90: WAY$ = "E"
  114. 1130 IF DIRECTION = 4 THEN ANGLE = 135: WAY$ = "SE"
  115. 1140 IF DIRECTION = 5 THEN ANGLE = 180: WAY$ = "S"
  116. 1150 IF DIRECTION = 6 THEN ANGLE = 225: WAY$ = "SW"
  117. 1160 IF DIRECTION = 7 THEN ANGLE = 270: WAY$ = "W"
  118. 1170 IF DIRECTION = 8 THEN ANGLE = 315: WAY$ = "NW"
  119. 1180 IF DIRECTION = 10 THEN ANGLE = LOOK
  120. 1190 REM *** "RIGHT" AND "RIGHT2" ARE THE AZIMUTH OF POINTS AT
  121. 1200 REM ***  90 DEGREE ANGLES TO THE PATH OF INTEREST.
  122. 1210 RIGHT = (ANGLE + 90) MOD 360: RIGHT2 = (ANGLE + 270) MOD 360
  123. 1220 IF WHICH = 3 OR COUNTR = 0 THEN IF ROUNDS = 0 THEN GOSUB 4270
  124. 1230 IF ROUNDS = 0 THEN MIDLATD = CIRLATD: MIDLOND = CIRLOND
  125. 1240 IF WHICH = 2 AND COUNTR = 0 THEN GOSUB 2810: REM SET UP GRAPH
  126. 1250 REM *** MIDLATD AND MIDLOND ARE THE SPOTS HALFWAY ALONG THE
  127. 1260 REM *** PATH OF INTEREST (THIS IS WHERE THE METEORS NEED TO BE).
  128. 1270 B = MIDLATD: L = MIDLOND
  129. 1280 B = B * R1: L = L * R1
  130. 1290 REM *** THIS SECTION DETERMINES THE AZ AND EL OF THE RADIANT BASED
  131. 1300 REM *** ON ITS R.A. AND DEC. AT PATH MIDPOINT.
  132. 1310 T5 = T - R + L: REM LHA
  133. 1320 COSDEG = COS(DEG): SINDEG = SIN(DEG)
  134. 1330 SINB = SIN(B)
  135. 1340 S1 = SINB * SINDEG
  136. 1350 COSINB = COS(B)
  137. 1360 S1 = S1 + COSINB * COSDEG * COS(T5)
  138. 1370 C1 = 1 - S1 * S1
  139. 1380 IF C1 > 0 THEN C1 = SQR(C1)
  140. 1390 IF C1 <= 0 THEN 1410
  141. 1400 H = ATN(S1 / C1): GOTO 1420
  142. 1410 H = SGN(S1) * P / 2
  143. 1420 C2 = (COSINB * SINDEG) - SINB * COSDEG * COS(T5)
  144. 1430 S2 = -COSDEG * SIN(T5)
  145. 1440 IF C2 = 0 THEN A = SGN(S2) * P / 2: GOTO 1470
  146. 1450 A = ATN(S2 / C2)
  147. 1460 IF C2 < 0 THEN A = A + P
  148. 1470 IF A < 0 THEN A = A + 2 * P
  149. 1480 ELEV = H / R1: AZIM = A / R1
  150. 1490 REM *** LOAD ARRAY WITH AZ, EL DATA
  151. 1500 IF WHICH <> 2 THEN 1550
  152. 1510 LAZIM(ENDER) = AZIM
  153. 1520 LELEV(ENDER) = ELEV
  154. 1530 LDATE(ENDER) = DAY
  155. 1540 LTIME(ENDER) = TIME
  156. 1550 IF ELEV < 0 THEN 1840
  157. 1560 QUAL = 0: BEST = 0
  158. 1570 REM *** ROUTINE TO INDICATE THE TIMES WHEN THE RADIANT IS
  159. 1580 REM *** WITHIN +/- 15 DEG OF PERPENDICULAR TO THE DESIRED
  160. 1590 REM *** PATH (GOOD) AND WHEN IT IS ALSO WITHIN +/- 15 DEG OF
  161. 1600 REM *** 45 DEG ELEVATION AT PATH MIDPOINT (BEST).
  162. 1605 IF ELEV < 20 AND WHICH = 4 THEN 1660
  163. 1610 IF ELEV < 20 THEN 1740
  164. 1620 IF (AZIM > (RIGHT - 15) AND AZIM < (RIGHT + 15)) OR (AZIM > (RIGHT2 - 15) AND AZIM < (RIGHT2 + 15)) THEN QUAL = 1
  165. 1630 IF QUAL = 1 AND ELEV > 30 AND ELEV < 60 THEN BEST = 1
  166. 1640 IF WHICH <> 4 THEN 1740
  167. 1650 IF BEST = 1 AND ABS(45 - ELEV) < ABS(45 - BESTEL) THEN OPTDIR = ANGLE: BESTEL = ELEV
  168. 1660 NEXT BESTDIR
  169. 1670 BEEP: COLOR 15
  170. 1680 IF OPTDIR > 1 THEN 1720
  171. 1690 PRINT : PRINT "NO GOOD DIRECTIONS AT"; TIME; "UTC."
  172. 1700 PRINT : PRINT "RUN OPTION 2 TO CHECK IF RADIANT IS ABOVE HORIZON"
  173. 1710 PRINT : PRINT : COLOR 7: GOTO 2200
  174. 1720 PRINT : PRINT "BEST DIRECTION AT"; TIME; "UTC ="; OPTDIR; "DEGREES"
  175. 1730 COLOR 7: GOTO 2200
  176. 1740 IF WHICH = 3 THEN 1790
  177. 1750 IF QUAL = 1 AND BEST = 0 THEN LOCATE 23, 10: PRINT "GOOD TIME:"; TIME
  178. 1760 COLOR 15
  179. 1770 IF BEST = 1 AND ABS(45 - ELEV) < ABS(45 - BESEL) THEN BESEL = ELEV: BESTIME = TIME
  180. 1780 COLOR 7
  181. 1790 IF WHICH = 3 AND HEADER = 0 THEN GOSUB 2990
  182. 1800 IF QUAL = 1 AND BEST = 0 AND WHICH = 3 THEN PRINT TIME, WAY$
  183. 1810 COLOR 15
  184. 1820 IF BEST = 1 AND WHICH = 3 THEN PRINT TAB(30); TIME, WAY$
  185. 1830 COLOR 7
  186. 1840 IF WHICH <> 2 THEN 2020
  187. 1850 IF COUNTR <> 0 THEN 1920
  188. 1860 LOCATE 21, 5
  189. 1870 PRINT "NORTH                        SOUTH                        NORTH"
  190. 1880 REM *** PLOT THE APPROXIMATE AZ, EL DATA FOR
  191. 1890 REM *** THE RADIANT AS A FUNCTION OF TIME.
  192. 1900 REM *** THE 'LOCATE' ARGUMENT IS DERIVED FROM
  193. 1910 REM *** INTEGER VALUES OF AZ AND EL.
  194. 1920 J = CINT(AZIM / 6) + 5
  195. 1930 I = CINT(20 - (ELEV / 5))
  196. 1940 IF I <= 0 THEN I = 1
  197. 1950 IF I > 20 THEN I = 20
  198. 1960 PNT$ = STR$(INT(TIME / 100))
  199. 1970 IF I = 20 THEN 2020
  200. 1980 REM *** HIGHLIGHT BEST TIMES ON THE GRAPH
  201. 1990 IF BEST = 1 THEN COLOR 15
  202. 2000 LOCATE I, J: PRINT "*"; PNT$
  203. 2010 COLOR 7
  204. 2020 TIMECOUNT = TIMECOUNT + INCR
  205. 2030 IF TIMECOUNT - (INT(TIMECOUNT / 100) * 100) >= 60 THEN TIMECOUNT = TIMECOUNT + 40
  206. 2040 TIME = TIME + INCR
  207. 2050 COUNTR = 1: ENDER = ENDER + 1
  208. 2060 ROUNDS = 1
  209. 2070 IF TIMECOUNT < FINISH THEN 910
  210. 2080 IF WHICH = 2 AND DIRECTION < 9 THEN LOCATE 23, 55: PRINT WAY$; " PATH"
  211. 2090 IF WHICH = 2 AND DIRECTION > 8 THEN LOCATE 23, 55: PRINT "BEARING:"; CINT(ANGLE); "DEG."
  212. 2100 IF WHICH = 3 THEN NEXT DIRECTION: BEEP: GOTO 2200
  213. 2110 IF BESTIME = 0 THEN 2130
  214. 2120 LOCATE 23, 30: PRINT "BEST TIME:"; BESTIME
  215. 2130 LOCATE 24, 10
  216. 2140 IF WHICH = 2 THEN INPUT "DO YOU WANT LISTED OUTPUT"; LISTED$
  217. 2150 IF LISTED$ = "Y" THEN PRINT : PRINT "                SHOWER: "; SHOWER$: PRINT
  218. 2160 IF LISTED$ = "Y" THEN PRINT "DAY", "TIME, UTC", "AZIMUTH", "ELEVATION" ELSE 2200
  219. 2170 FOR K = 1 TO ENDER - 1
  220. 2180 PRINT LDATE(K), LTIME(K), LAZIM(K), LELEV(K)
  221. 2190 NEXT K
  222. 2200 INPUT "DO YOU WANT ANOTHER RUN (Y/N)"; AGAIN$
  223. 2210 IF AGAIN$ = "Y" THEN COUNTR = 0: ENDER = 0: PRINTED = 0: BESTEL = 999
  224. 2220 IF AGAIN$ = "Y" THEN 280 ELSE 2400
  225. 2230 REM **************************************************
  226. 2240 REM   DATA FOR MAJOR (AND SOME MINOR) METEOR SHOWERS
  227. 2250 REM   FROM "ASTRONOMICAL CALENDAR 1985" BY GUY OTTWELL,
  228. 2260 REM   PHYSICS DEPT, FURMAN UNIV.,GREENVILLE, SC.
  229. 2270 REM **************************************************
  230. 2280 REM *** DATA FORMAT: NAME, E.L., MONTH, DAY, TIME ABOVE QUARTER MAX,
  231. 2290 REM *** VELOCITY (KM/SEC), APPROX. RATE, RADIANT R.A. HOURS, R.A. MINUTES,
  232. 2300 REM *** DECLINATION, CEPLECHA'S CLASS, HEIGHT OF IONIZATION (KM)
  233. 2310 DATA QUADRANTIDS,282.80,1,4,14 HOURS,41.5,110,15,28,50,B,100
  234. 2320 DATA LYRIDS,31.4,4,21,2.3 DAYS,47,VARIABLE,18,8,32,BC,105
  235. 2330 DATA ETA AQUARIDS,44,5,4,3 DAYS,67,21,22,20,-1,C2,115
  236. 2340 DATA ARIETIDS,75.0,6,5,RICH BUT SMALL,37,60,2,56,23,UNKNOWN,100
  237. 2350 DATA PERSEIDS,139.3,8,11,4.6 DAYS,60,68,3,4,58,C2,110
  238. 2360 DATA DRACONIDS, 196.3,10,10,1.2 HOURS,21,42,17,28,54,C1,97
  239. 2370 DATA ORIONIDS, 207,10,20,2 DAYS,67,35,6,20,15,C2,115
  240. 2380 DATA LEONIDS, 234.7,11,16,4 DAYS,71,40,10,8,22,C2,150
  241. 2390 DATA GEMINIDS, 261.9,12,13,2.6 DAYS,35,58,7,28,32,B,95
  242. 2400 KEY ON: END
  243. 2410 REM *********************************
  244. 2420 REM SEXAGESIMAL TO DECIMAL CONVERSION
  245. 2430 REM *********************************
  246. 2440 S = 1: A1 = ABS(VAL(A$))
  247. 2450 IF LEFT$(A$, 1) = "-" THEN S = -1
  248. 2460 A = S * (A1 + A2 / 60 + A3 / 3600)
  249. 2470 RETURN
  250. 2480 REM ***************************************
  251. 2490 REM GREENWICH MEAN SIDERIAL TIME CONVERSION
  252. 2500 REM ***************************************
  253. 2510 HOUR = INT(TIME / 100)
  254. 2520 MIN = TIME - (HOUR * 100)
  255. 2530 IF MIN >= 60 THEN TIME = TIME + 40: GOTO 2510
  256. 2540 IF TIME > 2400 THEN TIME = TIME - 2400: DAY = DAY + 1
  257. 2550 HOUR = HOUR / 24: MIN = MIN / 1440
  258. 2560 D = DAY + HOUR + MIN
  259. 2570 D1 = INT(D): F = D - D1 - .5
  260. 2580 J = -INT(7 * (INT((M + 9) / 12) + Y) / 4)
  261. 2590 S = SGN(M - 9): A = ABS(M - 9)
  262. 2600 J1 = INT(Y + S * INT(A / 7))
  263. 2610 J1 = -INT((INT(J1 / 100) + 1) * 3 / 4)
  264. 2620 J = J + INT(275 * M / 9) + D1 + J1
  265. 2630 J = J + 1721027! + 2 + 367 * Y
  266. 2640 IF F >= 0 THEN 2670
  267. 2650 F = F + 1: J = J - 1
  268. 2660 D = J - 2451545!
  269. 2670 T = D / 36525!: T1 = INT(T)
  270. 2680 J0 = T1 * 36525! + 2451545!
  271. 2690 T2 = (J - J0 + .5) / 36525!
  272. 2700 S = 24110.54841# + 184.812866# * T1
  273. 2710 S = S + 8640184.812866# * T2
  274. 2720 S = S + .093104 * T * T
  275. 2730 S = S - .0000062 * T * T * T
  276. 2740 S = S / 86400!: S = S - INT(S)
  277. 2750 S = 24 * (S + (F - .5) * 1.002737909#)
  278. 2760 IF S < 0 THEN S = S + 24
  279. 2770 IF S > 24 THEN S = S - 24
  280. 2780 RETURN
  281. 2790 REM *******************************
  282. 2800 REM ROUTINE TO INITIALIZE THE GRAPH
  283. 2810 REM *******************************
  284. 2820 CLS
  285. 2830 LOCATE 1, 22: PRINT "SHOWER: "; SHOWER$; "("; M; "/"; DAY; "/"; Y; ")"
  286. 2840 LOCATE 2, 13
  287. 2850 PRINT "AZ, EL OF RADIANT AT PATH MIDPOINT: LAT"; CINT(MIDLATD); "LON "; CINT(MIDLOND)
  288. 2860 FOR I = 2 TO 20
  289. 2870 LOCATE I, 3: PRINT (90 - (I * 5)) + 10
  290. 2880 NEXT I
  291. 2890 LOCATE 5, 1: PRINT "E": LOCATE 6, 1: PRINT "L": LOCATE 7, 1: PRINT "E"
  292. 2900 LOCATE 8, 1: PRINT "V": LOCATE 9, 1: PRINT "A": LOCATE 10, 1: PRINT "T"
  293. 2910 LOCATE 11, 1: PRINT "I": LOCATE 12, 1: PRINT "O": LOCATE 13, 1: PRINT "N"
  294. 2920 REM SET BOTTOM AXIS
  295. 2930 FOR J = 5 TO 65 STEP 5
  296. 2940 LOCATE 20, J - 1: PRINT (J - 5) * 6
  297. 2950 NEXT J
  298. 2960 LOCATE 11, 7: PRINT "-------------------------------------------------------------"
  299. 2970 RETURN
  300. 2980 REM *************************
  301. 2990 REM ROUTINE TO TITLE OPTION 3
  302. 3000 REM A************************
  303. 3010 CLS : PRINT "SHOWER: "; SHOWER$; "   DATE: "; M; "/"; DAY; "/"; Y; "  PEAK AT "; GMT; " UTC": PRINT :
  304. 3020 PRINT "    GOOD TIMES"
  305. 3030 COLOR 15
  306. 3040 LOCATE 3, 33: PRINT "BEST TIMES"
  307. 3050 COLOR 7
  308. 3060 HEADER = 1
  309. 3070 RETURN
  310. 3080 REM *********************************************
  311. 3090 REM ROUTINE TO CALCULATE ECLIPTIC LONGITUDE FROM
  312. 3100 REM 'THE ASTRONOMICAL ALMANAC FOR 1985' PAGE C24.
  313. 3110 REM *********************************************
  314. 3120 JC# = CDBL(J)
  315. 3130 FC# = CDBL(F)
  316. 3140 JD# = JC# + FC#
  317. 3150 REM *** JD# IS DOUBLE-PRECISION JULIAN DAY
  318. 3160 N# = JD# - 2451545#
  319. 3170 LONSUN# = 280.46 + (.9856474 * N#)
  320. 3180 G# = 357.528 + (.9856003 * N#)
  321. 3190 IF LONSUN# < 0 THEN LONSUN# = LONSUN# + 360!
  322. 3200 IF G# < 0 THEN G# = G# + 360!
  323. 3210 IF LONSUN# < 0 THEN 3190
  324. 3220 IF G# < 0 THEN 3200
  325. 3230 RCON# = 180! / 3.141592654#
  326. 3240 LONSUNT# = LONSUN# + (1.915 * SIN(G# / RCON#)) + (.02 * SIN(2 * (G# / RCON#)))
  327. 3250 RETURN
  328. 3260 REM *********************************************
  329. 3270 REM ROUTINE TO DETERMINE THE BEARING AND DISTANCE
  330. 3280 REM BETWEEN ANY TWO POINTS ON THE EARTH.
  331. 3290 REM *********************************************
  332. 3300 IF DIRECTION <> 9 THEN HISLATD = CIRLATD: HISLOND = CIRLOND
  333. 3310 DIFLOND = MYLOND - HISLOND
  334. 3320 MIDLATD = MYLATD - ((MYLATD - HISLATD) / 2)
  335. 3330 REM *** DIFFERENCE IN LONGITUDES MUST FALL BETWEEN -180 AND +180
  336. 3340 IF DIFLOND < -180 THEN DIFLOND = DIFLOND + 360
  337. 3350 IF DIFLOND > 180 THEN DIFLOND = DIFLOND - 360
  338. 3360 REM *** DEGREES TO RADIANS CONVERSION
  339. 3370 HISLAT = HISLATD * R1: HISLON = HISLOND * R1
  340. 3380 DIFLON = DIFLOND * R1
  341. 3390 REM *** DISTANCE CALCULATION
  342. 3400 COSB = (SMYLAT * SIN(HISLAT)) + (CMYLAT * COS(HISLAT) * COS(DIFLON))
  343. 3410 BETA = FNACOS(COSB)
  344. 3420 BETA2 = BETA / R1
  345. 3430 REM *** '69.05' IS THE CONVERSION FACTOR FOR STATUTE MILES.
  346. 3440 REM *** FOR KILOMETERS, USE 111.2, AND FOR NAUTICAL MILES 60.0.
  347. 3450 DIST = BETA2 * 69.05
  348. 3460 REM *** BEARING CALCULATION
  349. 3470 COSA = (SIN(HISLAT) - (SMYLAT * COSB)) / (CMYLAT * SIN(BETA))
  350. 3480 REM *** ROUNDING ERRORS SOMETIMES LET COSA>1 OR <-1 (ERROR)
  351. 3490 IF COSA > 1! THEN COSA = 1!
  352. 3500 IF COSA < -1! THEN COSA = -1!
  353. 3510 AZ = FNACOS(COSA)
  354. 3520 ANGLE = AZ / R1
  355. 3530 REM *** HAFLON IS THE LON OF A POINT BETWEEN HERE AND THERE
  356. 3540 HAFLON = FNACOS((COS(BETA / 2) - (SMYLAT * SIN(MIDLATD * R1))) / (CMYLAT * COS(MIDLATD * R1)))
  357. 3550 IF DIFLOND > 0 THEN ANGLE = 360! - ANGLE
  358. 3560 IF DIRECTION <> 9 OR PRINTED = 1 OR WHICH <> 2 THEN 3600
  359. 3570 PRINT : PRINT "DISTANCE: "; DIST; " MILES,"; BETA2 * 111.2; " KM"; "   BEARING:"; ANGLE; " DEGREES"
  360. 3580 INPUT "PRESS 'ENTER' TO CONTINUE"; PAUSE$
  361. 3590 PRINTED = 1
  362. 3600 IF ANGLE > 180 THEN HAFLON = MYLON - HAFLON ELSE HAFLON = MYLON + HAFLON
  363. 3610 MIDLOND = HAFLON / R1
  364. 3620 RETURN
  365. 3630 REM ************************************************************
  366. 3640 REM ROUTINE TO READ DATA AND CALCULATE PEAK DATE/TIME MODIFIED
  367. 3650 REM AFTER PROGRAMS BY RUSS WICKER (W4WD) AND JOE REISERT (W1JR).
  368. 3660 REM ************************************************************
  369. 3670 FOR I = 1 TO SHOWER
  370. 3680 READ SHOWER$, ELON, M, DAY, DURATION$, VELOCITY$, RATE$, RAHOUR, RAMIN, DEC, CLASS$, HEIGHT
  371. 3690 NEXT I
  372. 3700 RESTORE
  373. 3710 PRINT : PRINT : INPUT "        WHAT YEAR     [1990]  "; Y
  374. 3720 IF Y = 0 THEN Y = 1990
  375. 3730 TIME = 0
  376. 3740 GOSUB 2490
  377. 3750 GOSUB 3090
  378. 3760 IF LONSUNT# > ELON THEN 3810
  379. 3770 DAY = DAY + 1
  380. 3780 GOSUB 2490
  381. 3790 GOSUB 3090
  382. 3800 GOTO 3760
  383. 3810 IF LONSUNT# <= ELON THEN 3860
  384. 3820 E2 = LONSUNT#
  385. 3830 DAY = DAY - 1
  386. 3840 GOSUB 2490
  387. 3850 GOSUB 3090
  388. 3860 T = 24 * ((ELON - LONSUNT#) / (E2 - LONSUNT#))
  389. 3870 H0 = INT(T)
  390. 3880 M1 = INT(60 * (T - H0) + .5)
  391. 3890 GMT = 100 * H0 + M1
  392. 3900 IF GMT < 0 THEN DAY = DAY - 1: GOTO 3740
  393. 3910 IF DAY <= 31 THEN 3940
  394. 3920 DAY = DAY - 31
  395. 3930 M = M + 1
  396. 3940 CLS : PRINT : PRINT
  397. 3950 PRINT "THE "; SHOWER$; " METEOR SHOWER WILL PEAK ON"; M; "/"; DAY; "/"; Y
  398. 3960 PRINT "AT"; GMT; "UTC."
  399. 3970 IF WHICH > 1 THEN 700
  400. 3980 PRINT : PRINT : INPUT "MORE INFO ON THIS SHOWER    [Y]  "; MOREINFO$
  401. 3990 IF MOREINFO$ <> "N" THEN MOREINFO$ = "Y"
  402. 4000 IF MOREINFO$ <> "Y" THEN 4190
  403. 4010 PRINT
  404. 4020 PRINT "     SHOWER: "; SHOWER$
  405. 4030 PRINT : PRINT "DURATION ABOVE QUARTER MAX.: "; DURATION$
  406. 4040 PRINT "VELOCITY: "; VELOCITY$; " KM/SEC"
  407. 4050 PRINT "AVERAGE HEIGHT OF IONIZATION: "; HEIGHT; " KM"
  408. 4060 PRINT "METEORS PER HOUR (APPROX): "; RATE$
  409. 4070 PRINT "E.L. USED FOR CALCULATION: "; ELON; " DEGREES  (EPOCH 2000.0)"
  410. 4080 PRINT "R.A. OF RADIANT: "; RAHOUR; " HR "; RAMIN; " MIN"
  411. 4090 PRINT "DECLINATION:"; DEC; "DEGREES"
  412. 4100 PRINT "CEPLECHA'S CLASS: "; CLASS$
  413. 4110 TIME = GMT: GOSUB 2490: GOSUB 3090: ROUNDLON = INT(LONSUNT# * 1000) / 1000
  414. 4120 PRINT : PRINT "E.L. AT"; GMT; "="; ROUNDLON
  415. 4130 TIME = 0: GOSUB 2490: GOSUB 3090: ROUNDLON = INT(LONSUNT# * 1000) / 1000
  416. 4140 DEGLON = INT(LONSUNT#): MINLON = INT((LONSUNT# - DEGLON) * 60)
  417. 4150 SECLON = (INT((((LONSUNT# - DEGLON) * 60) - MINLON) * 60) * 100) / 100
  418. 4160 REM *** NEXT LINE IS DISPLAYED SO YOU CAN CHECK THE CALCULATED
  419. 4170 REM *** E.L. AGAINST THE NAUTICAL ALMANAC.
  420. 4180 PRINT "E.L. AT 0000 ="; ROUNDLON, "(="; DEGLON; "DEGREES"; MINLON; "MINUTES"; SECLON; "SECONDS)"
  421. 4190 PRINT : INPUT "DO YOU WANT ANOTHER RUN (Y/N)     [Y]   "; ANOTHER$
  422. 4200 IF ANOTHER$ <> "N" THEN ANOTHER$ = "Y"
  423. 4210 IF ANOTHER$ = "Y" THEN 300 ELSE 2400
  424. 4220 RETURN
  425. 4230 REM ****************************************************
  426. 4240 REM *** ROUTINE TO CALCULATE LAT, LON OF A 500-MI CIRCLE
  427. 4250 REM *** WHICH REPRESENTS THE 1000-MILE PATH MIDPOINT
  428. 4260 REM ****************************************************
  429. 4270 COSA2 = COS(ANGLE * R1): REM *** ANGLE IS THE BEARING FROM YOUR QTH
  430. 4280 REM *** CIRLATD IS THE LATITUDE OF THE POINT
  431. 4290 CIRLAT = FNARSIN((COSA2 * CMYLAT * SINBETA2) + (SMYLAT * COSBETA2))
  432. 4300 CIRLATD = CIRLAT / R1
  433. 4310 REM *** CIRLOND IS THE LONGITUDE OF THE POINT
  434. 4320 CIRLON = (COSBETA2 - (SMYLAT * SIN(CIRLAT))) / (CMYLAT * COS(CIRLAT))
  435. 4330 IF CIRLON > 1 THEN CIRLON = 1!
  436. 4340 IF CIRLON < -1 THEN CIRLON = -1!
  437. 4350 CIRLON = FNACOS(CIRLON)
  438. 4360 IF ANGLE > 180 THEN CIRLON = MYLON - CIRLON ELSE CIRLON = MYLON + CIRLON
  439. 4370 CIRLOND = CIRLON / R1
  440. 4380 RETURN
  441. 4390 REM *********************************************
  442. 4400 REM *** ROUTINE TO INITIALIZE VARIABLES WHICH ARE
  443. 4410 REM *** USED OFTEN.  THIS SPEEDS THINGS UP.
  444. 4420 REM *********************************************
  445. 4430 P = 3.141593: R1 = P / 180!
  446. 4440 MYLON = MYLOND * R1: MYLAT = MYLATD * R1
  447. 4450 CMYLAT = COS(MYLAT): SMYLAT = SIN(MYLAT)
  448. 4460 REM *** CIRRANGE=500 IS THE DISTANCE TO PATH MIDPOINT; THIS
  449. 4470 REM *** REPRESENTS A 1000-MILE RANGE; CHANGE FOR ANOTHER DISTANCE.
  450. 4480 CIRRANGE = 500: CIRBETA2 = (CIRRANGE / 69.05) * R1: REM FOR KM CHANGE 69.05 TO 111.2
  451. 4490 COSBETA2 = COS(CIRBETA2): SINBETA2 = SIN(CIRBETA2)
  452. 4500 RETURN
  453.  
  454.